Print came out smaller than actual dimensions  

RE: Print came out smaller than actual dimensions

the link appears to take me to dropbox, who want me to open an account. 

if you ZIP compress the files, you can attach the zip files directly in the forum, for free
regards Joan

RE: Print came out smaller than actual dimensions

Thanks, I've added the zip file below.

Help

RE: Print came out smaller than actual dimensions

If you really need 255mm, you are probably out of luck with a prusa mk4

as you can see the bed shape, is set to 250mm on the X axis, and I believe this is hard coded in firmware. 

however. looking at your model file in prusa slicer, there are a couple  of issues

1, there were errors in the STL    (there was an orange warning triangle next to the STL Name, in the right hand panel, (click on the triangle to repair the file..))

2, the model was slightly angled within the build space, so the overall dimensions showed 250mm on the X axis, but the model it's self was 248.07mm wide...
so there may be opportunity to increase it's size a tiny bit.  I have attached a revised version of your project file, below

This contains the repaired STL, and the re straightened location. 

Neat Amur JT

Regards Joan

RE:

If it really is 250mm, the max for your printer, the only way to get it to fit the bed may be to reduce the taper of the lid.  Your post reminded me that I need a couple of similar lids, so I designed a parametric version in OpenSCAD - basically a simple shape re-used several times to sculpt itself.  If you are not familiar with OpenSCAD (a free, open source download) you only need to edit the desired dimensions in the first few lines and the script will do the rest.

// Parametric round-corner lid

// dimensions of the box it must fit - adust accordingly
length=240;
width=190;
corner_radius=20; // outer
wall_thickness=3;

// required lid dimensions - adust accordingly
top_thickness=1.5;
outer_lid_wall_thickness=2;
inner_lid_wall_thickness=3;
outer_lid_depth=8; // not including top_thickness
inner_lid_depth=4; // not including top_thickness
outer_taper=20; // degrees

// how tight is the lid? - adust accordingly
tolerance=0.02;

// No more simple adjustments

layer=0.2;
$fn=100;  // curve accuracy

fla=sin(outer_taper)*outer_lid_depth;

difference(){
  hull(){
    shape(length+outer_lid_wall_thickness*2+fla*2,width+outer_lid_wall_thickness*2+fla*2,corner_radius+outer_lid_wall_thickness+fla,layer);
    translate([fla,fla,outer_lid_depth+top_thickness-layer]){
      shape(length+outer_lid_wall_thickness*2,width+outer_lid_wall_thickness*2,corner_radius+outer_lid_wall_thickness,layer);
    }
  }
  translate([fla+outer_lid_wall_thickness-tolerance,fla+outer_lid_wall_thickness-tolerance,top_thickness]){
    shape(length+tolerance*2,width+tolerance*2,corner_radius+tolerance,outer_lid_depth);
  }
}
translate([0,0,top_thickness]){
  difference(){
    translate([fla+outer_lid_wall_thickness+wall_thickness+tolerance*2,fla+outer_lid_wall_thickness+wall_thickness+tolerance*2,0]){
      shape(length-wall_thickness*2-tolerance*2,width-wall_thickness*2-tolerance*2,corner_radius-wall_thickness-tolerance,inner_lid_depth);
    }
    translate([fla+outer_lid_wall_thickness+wall_thickness+tolerance*2+inner_lid_wall_thickness,fla+outer_lid_wall_thickness+wall_thickness+tolerance*2+inner_lid_wall_thickness,0]){
      shape(length-wall_thickness*2-inner_lid_wall_thickness*2-tolerance*2,width-wall_thickness*2-inner_lid_wall_thickness*2-tolerance*2,corner_radius-wall_thickness-inner_lid_wall_thickness-tolerance,inner_lid_depth);
    }
  }
}

module shape(x,y,r,t){
  hull(){
    translate([r,r,0]){
      cylinder(r=r,h=t);
    }
    translate([r,y-r,0]){
      cylinder(r=r,h=t);
    }
    translate([x-r,y-r,0]){
      cylinder(r=r,h=t);
    }
    translate([x-r,r,0]){
      cylinder(r=r,h=t);
    }
  }
}

Which produces a shape like this:

Copy the script and paste it into OpenSCAD, render then export the STL file.

Hth, Cheerio,